# Interception des erreurs et signalement à l’utilisateur

Les fonctions s’appuyant sur des valeurs saisies par les utilisateurs sont susceptibles de provoquer des erreurs qu’il est indispensable de capturer :

* afin de signaler l’erreur à l’utilisateur au travers d’un message clair
* et empêcher certains calculs qui pourraient être utilisés par ailleurs alors qu’ils sont basés sur des données erronées.

Ces fonctions permettent généralement la validation des données saisies par un utilisateur et sont souvent associées à la fonction **SI**, afin d’indiquer un message clair en retour.

# Exemple 1 : avec RECHERCHEV

Les plages suivantes ont été nommées TAB\_PERSONNEL et TAB\_EMPLOI :

 (erreur fiche 1010 : EPM n’existe pas…)

Pour une paie donnée, la saisie des matricules est utile pour rechercher le nom et le prénom:



et la recherche correspondant au code emploi de l’employé :



Par chance, la somme des salaires provoque une erreur

## Avec une gestion d’erreur :

1. Tout d’abord une valeur d’erreur a été décidée et nommée dans une cellule (d’une feuille séparée en général)

Cela permettra d’avoir toujours le même texte en cas d’erreur

1. Une colonne de comptage des erreurs a été ajoutée (c’est-à-dire du nombre de fois où on trouve INDIC\_ERREUR dans la ligne, ici) :



1. et les formules ont évolué :
	1. en B3

=SI(ESTVIDE(A3);"";

SI(**ESTNA(**RECHERCHEV(A3;TAB\_PERSONNEL;2;FAUX)**)**;INDIC\_ERREUR;

RECHERCHEV(A3;TAB\_PERSONNEL;3;FAUX)&" "&RECHERCHEV(A3;TAB\_PERSONNEL;2;FAUX)

)

)

* 1. en C3

=SI(ESTVIDE(A3);"";

SI(**ESTNA(**RECHERCHEV(A3;TAB\_PERSONNEL;1;FAUX)**)**;INDIC\_ERREUR;

SI(**ESTNA(**RECHERCHEV(RECHERCHEV(A3;TAB\_PERSONNEL;4;FAUX);TAB\_EMPLOI;2;FAUX)**)**;INDIC\_ERREUR&" sur fiche";

RECHERCHEV(RECHERCHEV(A3;TAB\_PERSONNEL;4;FAUX);TAB\_EMPLOI;2;FAUX)

)

)

)

* 1. en C7 et E7

=SI(E7<>0;"calcul impossible";SOMME(C3:C6)) =SI(E7<>0;"calcul impossible";SOMME(D3:D6))

# Exemple 2 : avec INDEX et EQUIV

L’objectif est ici de rechercher le tarif d’un vin d’une certaine année :



Si le vin n’a pas été trouvé dans la liste des vins (RECHERCHEV), message « ce vin n’existe pas » :



Si l’année ou le vin n’a pas été trouvé (INDEX et EQUIV), ou bien si le tarif n’est pas renseigné (ESTVIDE), message « NON DISPONIBLE » :

 

Si le tarif est à 0.00, message « épuisé » (*remarquer l’utilisation du caractère joker « \* »*)

 

Sinon affichage du tarif :



## La formule est la suivante :

=SI(ESTNA(RECHERCHEV(G2;TAB\_NOMVIN;1;FAUX));

"ce vin n'existe pas";

SI(OU(ESTNA(INDEX(TAB\_TARIFVIN;EQUIV(G2;TAB\_NOMVIN;0);EQUIV(G3;TAB\_ANNEEVIN;0)));

ESTVIDE(INDEX(TAB\_TARIFVIN;EQUIV(G2;TAB\_NOMVIN;0); EQUIV(G3;TAB\_ANNEEVIN;0)))

);

"non disponible";

SI( INDEX(TAB\_TARIFVIN;EQUIV(G2;TAB\_NOMVIN;0); EQUIV(G3;TAB\_ANNEEVIN;0))=0;

" epuisé";

INDEX(TAB\_TARIFVIN;EQUIV(G2;TAB\_NOMVIN;0); EQUIV(G3;TAB\_ANNEEVIN;0))

)

)

)

Ce genre de formule nécessite une structuration claire pour éviter les erreurs.

On constate la répétition d’une même recherche : une solution permettant de simplifier la formule serait de

* réserver une cellule (*cachée de l’utilisateur, par exemple*) qui effectuerait la recherche systématique du tarif



* puis utiliser directement cette cellule dans la formule initiale :

La formule devient alors :

=SI(ESTNA(RECHERCHEV(G2;TAB\_NOMVIN;1;FAUX));

"ce vin n'existe pas";

SI(OU(ESTNA(RECH\_TARIF);

ESTVIDE(RECH\_TARIF)

);

"non disponible";

SI( RECH\_TARIF=0;

" épuisé";

RECH\_TARIF

)

)

)

=SI(ESTNA(RECHERCHEV(G2;TAB\_NOMVIN;1;FAUX));"ce vin n'existe pas"; SI(OU(ESTNA(RECH\_TARIF);ESTVIDE(RECH\_TARIF));"non disponible"; SI(RECH\_TARIF=0;" épuisé";RECH\_TARIF)))